;+
; NAME:
;    it_ppsav
; PURPOSE: (one line)
;    Save itool photometry parameters to a file.
; DESCRIPTION:
;
; CATEGORY:
;    Compound Widgets
; CALLING SEQUENCE:
;    it_ppsav, ph_parms
; INPUTS:
;    ph_parms : The photometry parameters structure (See itool.pro).
; OPTIONAL INPUT PARAMETERS:
;
; KEYWORD PARAMETERS:
;
; OUTPUTS:
;
; COMMON BLOCKS:
;
; SIDE EFFECTS:
;
; RESTRICTIONS:
;
; PROCEDURE:
;
; MODIFICATION HISTORY:
;    Written by Doug Loucks, Lowell Observatory, May 20, 1994. Formerly
; in it_ppmgr.
;-
; ------------------------------------------------------------------------------
; Procedure it_ppsav
; ------------------------------------------------------------------------------
PRO it_ppsav, ph_parms

IF ph_parms.parmfile EQ ' ' OR ph_parms.parmfile EQ '' THEN BEGIN
   MESSAGE, 'No photometry parameters file.' + STRING(7B), /INFO
   RETURN
ENDIF

fmt1 = '(G0.0,A)'

GET_LUN, lu
err = 0
OPENW, lu, ph_parms.parmfile, ERROR=err
IF err NE 0 THEN BEGIN
   FREE_LUN, lu
   MESSAGE, !error_state.msg + STRING(7B), /INFO
   RETURN
ENDIF

PRINTF, lu, ph_parms.parmfilever
PRINTF, lu, ph_parms.logfile, '   Photometry log file name'
PRINTF, lu, ph_parms.radius,  '   Aperture radius (pixels)', FORMAT=fmt1
PRINTF, lu, ph_parms.sky1,    '   Inner radius of sky annulus (pixels)', $
   FORMAT=fmt1
PRINTF, lu, ph_parms.sky2,    '   Outer radius of sky annulus (pixels)', $
   FORMAT=fmt1
PRINTF, lu, ph_parms.boxmrad, '   Local maximum box radius', FORMAT=fmt1
PRINTF, lu, ph_parms.gain,    '   Gain of CCD (e-/DN)', FORMAT=fmt1
PRINTF, lu, ph_parms.pscale,  '   Plate scale (arcseconds/pixel)', FORMAT=fmt1
PRINTF, lu, ph_parms.exact,   '   Exact position flag',      FORMAT=fmt1
PRINTF, lu, ph_parms.nomext,  '   Nominal extinction (mags/airmass)', $
   FORMAT=fmt1
PRINTF, lu, ph_parms.zpoint,  '   Zero point', FORMAT=fmt1

FREE_LUN, lu
MESSAGE, 'Photometry parameters saved to file ' + ph_parms.parmfile, /INFO

ph_parms.edtflg = 0

RETURN
END