;+
; NAME:
;    it_pplod
; PURPOSE: (one line)
;    Load itool photometry parameters from a file.
; DESCRIPTION:
;
; CATEGORY:
;    Compound Widgets
; CALLING SEQUENCE:
;    it_pplod, ph_parms
; INPUTS:
;    ph_parms : The photometry parameters structure (See itool.pro).
; OPTIONAL INPUT PARAMETERS:
;
; KEYWORD PARAMETERS:
;
; OUTPUTS:
;
; COMMON BLOCKS:
;
; SIDE EFFECTS:
;
; RESTRICTIONS:
;
; PROCEDURE:
;
; MODIFICATION HISTORY:
;    Written by Doug Loucks, Lowell Observatory, May 20, 1994. Formerly
; in it_ppmgr.
;-
; ------------------------------------------------------------------------------
; Procedure it_pplod
; ------------------------------------------------------------------------------
PRO it_pplod, ph_parms

IF ph_parms.parmfile EQ ' ' OR ph_parms.parmfile EQ '' THEN BEGIN
   MESSAGE, 'No photometry parameters file.' + STRING(7B), /INFO
   RETURN
ENDIF

IF ph_parms.edtflg THEN BEGIN
   tmsg = [ '\\\\\\ WARNING //////', $
   'PHOTOMETRY parameter changes have not been saved.', $
   'Do you wish to overwrite the existing parameters?' ]
   con = qannounc( tmsg, TITLE='Photometry Parameters Load Confirmation', $
         FALSE='No, cancel load request', TRUE='Yes, overwrite' )
   IF NOT con THEN RETURN
ENDIF

GET_LUN, lu
err = 0
OPENR, lu, ph_parms.parmfile, ERROR=err
IF err NE 0 THEN BEGIN
   FREE_LUN, lu
   MESSAGE, !error_state.msg + STRING(7B), /INFO
   RETURN
ENDIF

ph_parms.edtflg = 0

vid = ' '
READF, lu, vid
IF vid EQ ph_parms.parmfilever THEN BEGIN
   temp = ' '
   READF, lu, temp
   ph_parms.logfile = temp
   p = STRPOS( temp, ' ' )
   IF p GT 0 THEN BEGIN
      ph_parms.logfile = STRMID( temp, 0, p )
   ENDIF
   READF, lu, temp
   ph_parms.radius = temp
   READF, lu, temp
   ph_parms.sky1 = temp
   READF, lu, temp
   ph_parms.sky2 = temp
   READF, lu, temp
   ph_parms.boxmrad = temp
   READF, lu, temp
   ph_parms.gain = temp
   READF, lu, temp
   ph_parms.pscale = temp
   READF, lu, temp
   ph_parms.exact = temp
   READF, lu, temp
   ph_parms.nomext = temp
   READF, lu, temp
   ph_parms.zpoint = temp
   MESSAGE, 'Photometry parameters loaded from file ' + $
      ph_parms.parmfile, /INFO
ENDIF ELSE BEGIN
   MESSAGE, 'Unknown photometry parameters file format ' + vid + STRING(7B), $
   /INFO
ENDELSE

FREE_LUN, lu
RETURN
END